1. 触发器使用教程和命名规范  
  2.   
  3.   
  4. 目  录  
  5. 触发器使用教程和命名规范    1  
  6. 1，触发器简介 1  
  7. 2，触发器示例 2  
  8. 3，触发器语法和功能  3  
  9. 4，例一：行级触发器之一    4  
  10. 5，例二：行级触发器之二    4  
  11. 6，例三：INSTEAD OF触发器  6  
  12. 7，例四：语句级触发器之一   8  
  13. 8，例五：语句级触发器之二   9  
  14. 9，例六：用包封装触发器代码  10  
  15. 10，触发器命名规范  11  
  16.   
  17. 1，触发器简介  
  18. 触发器（Trigger）是数据库对象的一种，编码方式类似存储过程，与某张表（Table）相关联，当有DML语句对表进行操作时，可以引起触发器的执行，达到对插入记录一致性，正确性和规范性控制的目的。在当年C/S时代盛行的时候，由于客户端直接连接数据库，能保证数据库一致性的只有数据库本身，此时主键（Primary Key），外键（Foreign Key），约束（Constraint）和触发器成为必要的控制机制。而触发器的实现比较灵活，可编程性强，自然成为了最流行的控制机制。到了B/S时代，发展成4层架构，客户端不再能直接访问数据库，只有中间件才可以访问数据库。要控制数据库的一致性，既可以在中间件里控制，也可以在数据库端控制。很多的青睐Java的开发者，随之将数据库当成一个黑盒，把大多数的数据控制工作放在了Servlet中执行。这样做，不需要了解太多的数据库知识，也减少了数据库编程的复杂性，但同时增加了Servlet编程的工作量。从架构设计来看，中间件的功能是检查业务正确性和执行业务逻辑，如果把数据的一致性检查放到中间件去做，需要在所有涉及到数据写入的地方进行数据一致性检查。由于数据库访问相对于中间件来说是远程调用，要编写统一的数据一致性检查代码并非易事，一般采用在多个地方的增加类似的检查步骤。一旦一致性检查过程发生调整，势必导致多个地方的修改，不仅增加工作量，而且无法保证每个检查步骤的正确性。触发器的应用，应该放在关键的，多方发起的，高频访问的数据表上，过多使用触发器，会增加数据库负担，降低数据库性能。而放弃使用触发器，则会导致系统架构设计上的问题，影响系统的稳定性。  
  19.   
  20.   
  21. 2，触发器示例  
  22. 触发器代码类似存储过程，以PL/SQL脚本编写。下面是一个触发器的示例：  
  23. 新建员工工资表salary  
  24. create table SALARY  
  25. (  
  26.   EMPLOYEE_ID NUMBER, --员工ID  
  27.   MONTH       VARCHAR2(6), --工资月份  
  28.   AMOUNT      NUMBER --工资金额  
  29. )  
  30.   
  31. 创建与salary关联的触发器salary_trg_rai  
  32. 1   Create or replace trigger salary_trg_rai  
  33. 2   After insert on salary  
  34. 3   For each row  
  35. 4   declare  
  36. 5   Begin  
  37. 6     Dbms_output.put_line(‘员工ID：’ || :new.employee_id);  
  38. 7     Dbms_output.put_line(‘工资月份：’ || :new.month);  
  39. 8     Dbms_output.put_line(‘工资：’ || :new.amount);  
  40. 9     Dbms_output.put_line(‘触发器已被执行’);  
  41. 10   End;  
  42. 打开一个SQL Window窗口（使用PL/SQL Developer工具），或在sqlplus中输入：  
  43. Insert into salary(employee_id, month, amount) values(1, ‘200606’, 10000);  
  44. 执行后可以在sqlplus中，或在SQL Window窗口的Output中见到  
  45. 员工ID：1  
  46. 工资月份：200606  
  47. 工资：10000  
  48. 触发器已执行  
  49.   
  50. 在代码的第一行，定义了数据库对象的类型是trigger，定义触发器的名称是salary_trg_rai  
  51. 第二行说明了这是一个after触发器，在DML操作实施之后执行。紧接着的insert说明了这是一个针对insert操作的触发器，每个对该表进行的insert操作都会执行这个触发器。  
  52. 第三行说明了这是一个针对行级的触发器，当插入的记录有n条时，在每一条插入操作时都会执行该触发器，总共执行n次。  
  53. Declare后面跟的是本地变量定义部分，如果没有本地变量定义，此部分可以为空  
  54. Begin和end括起来的代码，是触发器的执行部分，一般会对插入记录进行一致性检查，在本例中打印了插入的记录和“触发器已执行”。  
  55. 其中:new对象表示了插入的记录，可以通过:new.column_name来引用记录的每个字段值  
  56.   
  57.   
  58. 3，触发器语法和功能  
  59. 触发器的语法如下  
  60. CREATE OR REPLACE TRIGGER trigger_name  
  61. <before | after | instead of> <insert | update | delete> ON table_name  
  62. [FOR EACH ROW]  
  63. WHEN (condition)  
  64. DECLARE  
  65. BEGIN  
  66.     --触发器代码  
  67. END;  
  68.   
  69. Trigger_name 是触发器的名称。<before | after | instead of>可以选择before或者after或instead of。 Before表示在DML语句实施前执行触发器，而after表示在在dml语句实施之后执行触发器，instead of触发器用在对视图的更新上。<insert | update | delete>可以选择一个或多个DML语句，如果选择多个，则用or分开，如：insert or update。Table_name是触发器关联的表名。  
  70. [FOR EACH ROW]为可选项，如果注明了FOR EACH ROW，则说明了该触发器是一个行级的触发器，DML语句处理每条记录都会执行触发器；否则是一个语句级的触发器，每个DML语句触发一次。  
  71. WHEN后跟的condition是触发器的响应条件，只对行级触发器有效，当操作的记录满足condition时，触发器才被执行，否则不执行。Condition中可以通过new对象和old对象（注意区别于前面的:new和:old，在代码中引用需要加上冒号）来引用操作的记录。  
  72. 触发器代码可以包括三种类型：未涉及数据库事务代码，涉及关联表（上文语法中的table_name）数据库事务代码，涉及除关联表之外数据库事务代码。其中第一种类型代码只对数据进行简单运算和判断，没有DML语句，这种类型代码可以在所有的触发器中执行。第二种类型代码涉及到对关联表的数据操作，比如查询关联表的总记录数或者往关联表中插入一条记录，该类型代码只能在语句级触发器中使用，如果在行级触发器中使用，将会报ORA-04091错误。第三种类型代码涉及到除关联表之外的数据库事务，这种代码可以在所有触发器中使用。  
  73.   
  74. 从触发器的功能上来看，可以分成3类：  
  75.    重写列（仅限于before触发器）  
  76.    采取行动（任何触发器）  
  77.    拒绝事务（任何触发器）  
  78. “重写列”用于对表字段的校验，当插入值为空或者插入值不符合要求，则触发器用缺省值或另外的值代替，在多数情况下与字段的default属性相同。这种功能只能在行级before触发器中执行。“采取行动”针对当前事务的特点，对相关表进行操作，比如根据当前表插入的记录更新其他表，银行中的总帐和分户帐间的总分关系就可以通过这种触发器功能来维护。“拒绝事务”用在对数据的合法性检验上，当更新的数据不满足表或系统的一致性要求，则通过抛出异常的方式拒绝事务，在其上层的代码可以捕获这个异常并进行相应操作。  
  79.   
  80. 下面将通过举例说明，在例子中将触发器主体的语法一一介绍，读者可以在例子中体会触发器的功能。  
  81.   
  82. 4，例一：行级触发器之一  
  83. CREATE OR REPLACE TRIGGER salary_raiu  
  84. AFTER INSERT OR UPDATE OF amount ON salary  
  85. FOR EACH ROW  
  86. BEGIN  
  87.     IF inserting THEN  
  88.         dbms_output.put_line(‘插入’);  
  89.     ELSIF updating THEN  
  90. dbms_output.put_line(‘更新amount列’);  
  91.     END IF；  
  92. END;  
  93. 以上是一个after insert和after update的行级触发器。在第二行中of amount on salary的意思是只有当amount列被更新时，update触发器才会有效。所以，以下语句将不会执行触发器：  
  94. Update salary set month = ‘200601’ where month = ‘200606’;  
  95. 在触发器主体的if语句表达式中，inserting, updating和deleting可以用来区分当前是在做哪一种DML操作，可以作为把多个类似触发器合并在一个触发器中判别触发事件的属性。  
  96.   
  97. 5，例二：行级触发器之二  
  98. 新建员工表employment  
  99. CREATE TABLE EMPLOYMENT  
  100. (  
  101.   EMPLOYEE_ID NUMBER, --员工ID  
  102.   MAXSALARY   NUMBER --工资上限  
  103. )  
  104. 插入两条记录  
  105. Insert into employment values(1, 1000);  
  106. Insert into employment values(2, 2000);  
  107.   
  108. CREATE OR REPLACE TRIGGER salary_raiu  
  109. AFTER INSERT OR UPDATE OF amount ON salary  
  110. FOR EACH ROW  
  111. WHEN ( NEW.amount >= 1000 AND (old.amount IS NULL OR OLD.amount <= 500))  
  112. DECLARE  
  113.     v_maxsalary NUMBER;  
  114. BEGIN  
  115.     SELECT maxsalary  
  116.         INTO v_maxsalary  
  117.         FROM employment  
  118.      WHERE employee_id = :NEW.employee_id;  
  119.     IF :NEW.amount > v_maxsalary THEN  
  120.         raise_application_error(-20000, '工资超限');  
  121.     END IF;  
  122. END;  
  123.   
  124. 以上的例子引入了一个新的表employment，表中的maxsalary字段代表该员工每月所能分配的最高工资。下面的触发器根据插入或修改记录的 employee_id，在employment表中查到该员工的每月最高工资，如果插入或修改后的amount超过这个值，则报错误。  
  125. 代码中的when子句表明了该触发器只针对修改或插入后的amount值超过1000，而修改前的amount值小于500的记录。New对象和old对象分别表示了操作前和操作后的记录对象。对于insert操作，由于当前操作记录无历史对象，所以old对象中所有属性是null；对于delete操作，由于当前操作记录没有更新对象，所以new对象中所有属性也是null。但在这两种情况下，并不影响old和new对象的引用和在触发器主体中的使用，和普通的空值作同样的处理。  
  126. 在触发器主体中，先通过:new.employee_id，得到该员工的工资上限，然后在if语句中判断更新后的员工工资是否超限，如果超限则错误代码为-20000，错误信息为“工资超限”的自定义错误。其中的raise_application_error包含两个参数，前一个是自定义错误代码，后一个是自定义错误代码信息。其中自定义错误代码必须小于或等于-20000。执行完该语句后，一个异常被抛出，如果在上一层有exception子句，该异常将被捕获。如下面代码：  
  127. DECLARE  
  128.     code NUMBER;  
  129.     msg  VARCHAR2(500);  
  130. BEGIN  
  131.     INSERT INTO salary (employee_id, amount) VALUES (2, 5000);  
  132. EXCEPTION  
  133.     WHEN OTHERS THEN  
  134.         code := SQLCODE;  
  135.         msg  := substr(SQLERRM, 1, 500);  
  136.         dbms_output.put_line(code);  
  137.         dbms_output.put_line(msg);  
  138. END;  
  139. 执行后，将在output中或者sqlplus窗口中见着以下信息：  
  140. -20000  
  141. ORA-20000: 工资超出限制  
  142. ORA-06512: 在"SCOTT.SALARY_RAI", line 9  
  143. ORA-04088: 触发器 'SCOTT.SALARY_RAI' 执行过程中出错  
  144.   
  145. 这里的raise_application_error相当于拒绝了插入或者修改事务，当上层代码接受到这个异常后，判断该异常代码等于-20000，可以作出回滚事务或者继续其他事务的处理。  
  146.   
  147. 以上两个例子中用到的inserting, updating, deleting和raise_application_error都是dbms_standard包中的函数，具体的说明可以参照Oracle的帮助文档。  
  148. create or replace package sys.dbms_standard is  
  149.   procedure raise_application_error(num binary_integer, msg varchar2,  
  150.   function inserting return boolean;  
  151.   function deleting  return boolean;  
  152.   function updating  return boolean;  
  153.   function updating (colnam varchar2) return boolean;  
  154. end;  
  155.   
  156. 对于before和after行级触发器，:new和:old对象的属性值都是一样的，主要是对于在Oracle约束（Constraint）之前或之后的执行触发器的选择。需要注意的是，可以在before行触发器中更改:new对象中的值，但是在after行触发器就不行。  
  157.   
  158. 下面介绍一种instead of触发器，该触发器主要使用在对视图的更新上，以下是instead of触发器的语法：  
  159. CREATE OR REPLACE TRIGGER trigger_name  
  160. INSTEAD OF <insert | update | delete> ON view_name  
  161. [FOR EACH ROW]  
  162. WHEN (condition)  
  163. DECLARE  
  164. BEGIN  
  165.     --触发器代码  
  166. END;  
  167.   
  168. 其他部分语法同前面所述的before和after语法是一样的，唯一不同的是在第二行用上了instead of关键字。对于普通的视图来说，进行 insert等操作是被禁止的，因为Oracle无法知道操作的字段具体是哪个表中的字段。但我们可以通过建立instead of触发器，在触发器主体中告诉Oracle应该更新，删除或者修改哪些表的哪部分字段。如：  
  169.   
  170. 6，例三：instead of触发器  
  171. 新建视图  
  172. CREATE VIEW employee_salary(employee_id, maxsalary, MONTH, amount) AS   
  173. SELECT a.employee_id, a.maxsalary, b.MONTH, b.amount  
  174. FROM employment a, salary b  
  175. WHERE a.employee_id = b.employee_id  
  176.   
  177. 如果执行插入语句  
  178. INSERT INTO employee_salary(employee_id, maxsalary, MONTH, amount)  
  179. VALUES(10, 100000, '200606', 10000);  
  180. 系统会报错：  
  181. ORA-01779：无法修改与非键值保存表对应的列  
  182.   
  183. 我们可以通过建立以下的instead of存储过程，将插入视图的值分别插入到两个表中：  
  184. create or replace trigger employee_salary_rii  
  185.   instead of insert on employee_salary    
  186.   for each ROW  
  187. DECLARE  
  188.     v_cnt NUMBER;  
  189. BEGIN  
  190.   --检查是否存在该员工信息  
  191.     SELECT COUNT(*)  
  192.         INTO v_cnt  
  193.         FROM employment  
  194.      WHERE employee_id = :NEW.employee_id;  
  195.     IF v_cnt = 0 THEN  
  196.         INSERT INTO employment  
  197.             (employee_id, maxsalary)  
  198.         VALUES  
  199.             (:NEW.employee_id, :NEW.maxsalary);  
  200.     END IF;  
  201.   --检查是否存在该员工的工资信息  
  202.     SELECT COUNT(*)  
  203.         INTO v_cnt  
  204.         FROM salary  
  205.      WHERE employee_id = :NEW.employee_id  
  206.          AND MONTH = :NEW.MONTH;  
  207.     IF v_cnt = 0 THEN  
  208.         INSERT INTO salary  
  209.             (employee_id, MONTH, amount)  
  210.         VALUES  
  211.             (:NEW.employee_id, :NEW.MONTH, :NEW.amount);  
  212.     END IF;  
  213. END employee_salary_rii;  
  214.   
  215. 该触发器被建立后，执行上述insert操作，系统就会提示成功插入一条记录。  
  216. 但需要注意的是，这里的“成功插入一条记录”，只是Oracle并未发现触发器中有异常抛出，而根据insert语句中涉及的记录数作出一个判断。若触发器的主体什么都没有，只是一个空语句，Oracle也会报“成功插入一条记录”。同样道理，即使在触发器主体里往多个表中插入十条记录，Oracle的返回也是“成功插入一条记录”。  
  217.   
  218.   
  219.   
  220.   
  221. 行级触发器可以解决大部分的问题，但是如果需要对本表进行扫描检查，比如要检查总的工资是否超限了，用行级触发器是不行的，因为行级触发器主体中不能有涉及到关联表的事务，这时就需要用到语句级触发器。以下是语句级触发器的语法：  
  222. CREATE OR REPLACE TRIGGER trigger_name  
  223. <before | after | instead of ><insert | update | delete > ON table_name  
  224. DECLARE  
  225. BEGIN  
  226.     --触发器主体  
  227. END;  
  228.   
  229. 从语法定义上来看，行级触发器少了for each row，也不能使用when子句来限定入口条件，其他部分都是一样的，包括insert, update, delete和instead of都可以使用。  
  230.   
  231.   
  232. 7，例四：语句级触发器之一  
  233. CREATE OR REPLACE TRIGGER salary_saiu  
  234. AFTER INSERT OR UPDATE OF amount ON salary  
  235. DECLARE  
  236.     v_sumsalary NUMBER;  
  237. BEGIN  
  238.   SELECT SUM(amount) INTO v_sumsalary FROM salary;  
  239.     IF v_sumsalary > 500000 THEN  
  240.         raise_application_error(-20001, '总工资超过500000');  
  241.     END IF;  
  242. END;  
  243.   
  244. 以上代码定义了一个语句级触发器，该触发器检查在insert和update了amount字段后操作后，工资表中所有工资记录累加起来是否超过500000，如果超过则抛出异常。从这个例子可以看出，语句级触发器可以对关联表表进行扫描，扫描得到的结果可以用来作为判断一致性的标志。需要注意的是，在 before语句触发器主体和after语句触发器主体中对关联表进行扫描，结果是不一样的。在before语句触发器主体中扫描，扫描结果将不包括新插入和更新的记录，也就是说当以上代码换成 before触发器后，以下语句将不报错：  
  245. INSERT INTO salary(employee_id, month, amount) VALUEs(2, '200601', 600000)  
  246. 这是因为在主体中得到的v_sumsalary并不包括新插入的600000工资。  
  247. 另外，在语句级触发器中不能使用:new和:old对象，这一点和行级触发器是显著不同的。如果需要检查插入或更新后的记录，可以采用临时表技术。  
  248. 临时表是一种Oracle数据库对象，其特点是当创建数据的进程结束后，进程所创建的数据也随之清除。进程与进程不可以互相访问同一临时表中对方的数据，而且对临时表进行操作也不产生undo日志，减少了数据库的消耗。具体有关临时表的知识，可以参看有关书籍。  
  249. 为了在语句级触发器中访问新插入后修改后的记录，可以增加行级触发器，将更新的记录插入临时表中，然后在语句级触发器中扫描临时表，获得修改后的记录。临时表的表结构一般与关联表的结构一致。  
  250.   
  251.   
  252. 8，例五：语句级触发器之二  
  253. 目的：限制每个员工的总工资不能超过50000，否则停止对该表操作。  
  254. 创建临时表  
  255. create global temporary table SALARY_TMP  
  256. (  
  257.   EMPLOYEE_ID NUMBER,  
  258.   MONTH       VARCHAR2(6),  
  259.   AMOUNT      NUMBER  
  260. )  
  261. on commit delete rows;  
  262.   
  263. 为了把操作记录插入到临时表中，创建行级触发器：  
  264. CREATE OR REPLACE TRIGGER salary_raiu  
  265. AFTER INSERT OR UPDATE OF amount ON salary  
  266. FOR EACH ROW  
  267. BEGIN  
  268.   INSERT INTO salary_tmp(employee_id, month, amount)  
  269.   VALUES(:NEW.employee_id, :NEW.MONTH, :NEW.amount);  
  270. END;  
  271. 该触发器的作用是把更新后的记录信息插入到临时表中，如果更新了多条记录，则每条记录都会保存在临时表中。  
  272.   
  273. 创建语句级触发器：  
  274. CREATE OR REPLACE TRIGGER salary_sai  
  275. AFTER INSERT OR UPDATE OF amount ON salary  
  276. DECLARE  
  277.     v_sumsalary NUMBER;  
  278. BEGIN  
  279.     FOR cur IN (SELECT * FROM salary_tmp) LOOP  
  280.         SELECT SUM(amount)  
  281.             INTO v_sumsalary  
  282.             FROM salary  
  283.          WHERE employee_id = cur.employee_id;  
  284.         IF v_sumsalary > 50000 THEN  
  285.             raise_application_error(-20002, '员工累计工资超过50000');  
  286.         END IF;  
  287.     DELETE FROM salary_tmp;  
  288.     END LOOP;  
  289. END;  
  290.   
  291. 该触发器首先用游标从salary_tmp临时表中逐条读取更新或插入的记录，取employee_id，在关联表salary中查找所有相同员工的工资记录，并求和。若某员工工资总和超过50000，则抛出异常。如果检查通过，则清空临时表，避免下次检查相同的记录。  
  292. 执行以下语句：  
  293. INSERT INTO salary(employee_id, month, amount) VALUEs(7, '200601', 20000);  
  294. INSERT INTO salary(employee_id, month, amount) VALUEs(7, '200602', 20000);  
  295. INSERT INTO salary(employee_id, month, amount) VALUEs(7, '200603', 20000);  
  296. 在执行第三句时系统报错：  
  297. ORA-20002：员工累计工资超过50000  
  298. 查询salary表，发现前两条记录正常插入了，第三条记录没有插入。  
  299.   
  300.   
  301. 如果系统结构比较复杂，而且触发器的代码比较多，在触发器主体中写过多的代码，对于维护来说是一个困难。这时可以将所有触发器的代码写到同一个包中，不同的触发器代码以不同的存储过程封装，然后触发器主体中调用这部分代码。  
  302.   
  303. 9，例六：用包封装触发器代码  
  304. 目的：改写例五，封装触发器主体代码  
  305. 创建代码包：  
  306. CREATE OR REPLACE PACKAGE BODY salary_trigger_pck IS  
  307.   
  308.     PROCEDURE load_salary_tmp(i_employee_id IN NUMBER,  
  309.                             i_month       IN VARCHAR2,  
  310.                             i_amount      IN NUMBER) IS  
  311.     BEGIN  
  312.         INSERT INTO salary_tmp VALUES (i_employee_id, i_month, i_amount);  
  313.     END load_salary_tmp;  
  314.   
  315.     PROCEDURE check_salary IS  
  316.         v_sumsalary NUMBER;  
  317.     BEGIN  
  318.         FOR cur IN (SELECT * FROM salary_tmp) LOOP  
  319.             SELECT SUM(amount)  
  320.                 INTO v_sumsalary  
  321.                 FROM salary  
  322.              WHERE employee_id = cur.employee_id;  
  323.             IF v_sumsalary > 50000 THEN  
  324.                 raise_application_error(-20002, '员工累计工资超过50000');  
  325.             END IF;  
  326.             DELETE FROM salary_tmp;  
  327.         END LOOP;  
  328.     END check_salary;  
  329. END salary_trigger_pck;  
  330. 包salary_trigger_pck中有两个存储过程，load_salary_tmp用于在行级触发器中调用，往salary_tmp临时表中装载更新或插入记录。而check_salary用于在语句级触发器中检查员工累计工资是否超限。  
  331.   
  332. 修改行级触发器和语句级触发器：  
  333. CREATE OR REPLACE TRIGGER salary_raiu  
  334.     AFTER INSERT OR UPDATE OF amount ON salary  
  335.     FOR EACH ROW  
  336. BEGIN  
  337.     salary_trigger_pck.load_salary_tmp(:NEW.employee_id,     :NEW.MONTH, :NEW.amount);  
  338. END;  
  339.   
  340. CREATE OR REPLACE TRIGGER salary_sai  
  341. AFTER INSERT OR UPDATE OF amount ON salary  
  342. BEGIN  
  343.     salary_trigger_pck.check_salary;  
  344. END;  
  345.   
  346. 这样主要代码就集中到了salary_trigger_pck中，触发器主体中只实现了一个调用功能。  
  347.   
  348. 10，触发器命名规范  
  349. 为了方便对触发器命名和根据触发器名称了解触发器含义，需要定义触发器的命名规范：  
  350. Trigger_name = table_name_trg_<R|S><A|B|I><I|U|D>  
  351.   
  352. 触发器名限于30个字符。必须缩写表名，以便附加触发器属性信息。  
  353. <R|S>基于行级（row）还是语句级（statement）的触发器  
  354. <A|B|I>after, before或者是instead of触发器  
  355. <I|U|D>触发事件是insert，update还是delete。如果有多个触发事件则连着写  
  356.   
  357. 例如：  
  358. Salary_rai      salary表的行级after触发器，触发事件是insert  
  359. Employee_sbiud  employee表的语句级before触发器，触发事件是insert,update和delete